/*
Bug list
1. Don't use string "\n" in expression.
2. Don't use same var name ex: $sampleString,$sample
*/

global proc ho_convertExpressionString(){
	if(`window -exists "ho_convertExpressionString"`){
		deleteUI -window "ho_convertExpressionString";
	}
	window -title "ho_convertExpressionString" -rtf 1 "ho_convertExpressionString";

	int $fieldWidth = 400;
	int $replaceLayoutWidth = 300;
	rowLayout -numberOfColumns 2 -columnWidth2 $fieldWidth $replaceLayoutWidth;
		columnLayout;
			text -l "Input String (Paste Your Expression Here.)";
			scrollField -w $fieldWidth -h 200 -text "" inputString;
			button -l "Convert" -w $fieldWidth -c "convertString()" convert;
			text -l "Converted String";
			scrollField -w $fieldWidth -h 200 -ed 1 -text "" convertedString;

			text -l "hosok2@naver.com";
		setParent..;
		
		columnLayout;
			text -l "Replace Variables";
			text -l "Select string in input string field and push Add Variable button.";
			rowLayout -numberOfColumns 2 -columnWidth2 ($replaceLayoutWidth/2) ($replaceLayoutWidth/2);
				button -w ($replaceLayoutWidth/2) -c "addVarButton()" -l "Add Variable";
				button -w ($replaceLayoutWidth/2) -c "removeAllVariables()" -l "Remove All Variables";
				setParent..;
			text -l "Expression String Variable Name";
			textField -tx "expressionString" -w 300 expressionStringVarName;
			separator -w $replaceLayoutWidth;
			text -l "Variable List" variableListText;
			columnLayout variableList;
		setParent..;

	showWindow;
}

global proc convertString(){
	
	string $expressionVarName =`textField -q -tx expressionStringVarName`;
	string $inputString = `scrollField -q -text inputString`;
	string $convertedString = "";

	string $targetString = "";
	string $newString = "";
	string $buffer[];
	//clear($buffer);
	$inputString = `encodeString $inputString`;
	tokenize $inputString $buffer;

	string $varLayouts[] = `columnLayout -q -childArray variableList`;
	for($n = 0 ; $n <= size($varLayouts) ; $n++){
		if($n != 0){
			string $childrenOfVarLayout[] = `rowLayout -q -childArray $varLayouts[$n-1]`;
			$targetString = `textField -q -tx $childrenOfVarLayout[0]`;
			$newString = `textField -q -tx $childrenOfVarLayout[2]`;
			$newString = "\"+ " + $newString + " +\"";
		}
		for($m = 0 ; $m <size($buffer); $m++){
			$buffer[$m] = `substitute $targetString $buffer[$m] $newString`;
			if(`gmatch $buffer[$m] "*\\n*"`){
				$buffer[$m] = `substitute "\\\\n" $buffer[$m] "\n"`;
			}
		}
	}
	$convertedString = stringArrayToString($buffer," ");

	clear($buffer);
	tokenize $convertedString "\n" $buffer;
	
	for($n = 0 ; $n < size($buffer) ; $n++){
		$buffer[$n] = "$"+$expressionVarName+" += \""+ $buffer[$n] +"\"\;";
	}
	$convertedString = stringArrayToString($buffer,"\n");
	$convertedString = "string $"+$expressionVarName+ " = \"\"\;\n" + $convertedString;
	scrollField -e -text $convertedString convertedString;
}

global proc removeAllVariables(){

	string $varLayouts[] = `columnLayout -q -childArray variableList`;

	for($n = 0 ; $n < size($varLayouts) ; $n++){
		deleteUI $varLayouts[$n];
	}
}

global proc addVarButton(){
	int $numOfVarButtons = `columnLayout -q -numberOfChildren variableList`;
	string $selectedString = `scrollField -q -selection inputString`;

	setParent variableList;
		string $laoutName = `rowLayout -numberOfColumns 4 -columnWidth4 110 30 110 100`;
		textField -tx $selectedString -w 100;
		text -l " --->";
		textField -w 100 -text ("$"+$selectedString);
		button -l "Remove" -c ("deleteUI "+$laoutName);
	setParent..;
}